WPF / Silverlight uygulamalarını çalıştırmak için IIS 5.0 ve IIS 6.0 ayarları

Özgür Belül — Sun, 06 Jul 2008 20:38:20 GMT

Multipurpose Internet Mail Extensions (MIME) uygun şekilde yapılandırıldığı sürece WPF uygulamalarınızı web serverlardan çalıştırabilirsiniz. IIS 7.0’da bu ayarlar yapılı olarak geldiği için bir sorun yok ancak IIS5.0 ve IIS6.0 için durum aynı değil.

Başlat menüsünden çalıştıra %SystemRoot%\system32\inetsrv\iis.msc yazıp enter’a basın ve Internet Information Services (IIS) Manager’ı çalıştırın.

Default WebSite’a gelip sağ klik properties’e girin. HTTP Headers sekmesini secip Enable Content Expiration seçeneğini 1 dakika olarak ayarlayın.

Aşağıdaki script’i notepad’de açıp .vbs uzantılı olarak kaydedin ve üzerine çift tıklayın. İş bittiğinde Presentation Foundation MIME tipleri kaydedildi. mesajı gelecek karşınıza.

Dim MimeMapObj, MimeMapArray, MimeTypesToAddArray, WshShell, oExec
Const ADS_PROPERTY_UPDATE = 2

MimeTypesToAddArray = Array(".manifest", "application/manifest", ".xaml", _
    "application/xaml+xml", ".application", "application/x-ms-application", _
    ".deploy", "application/octet-stream", ".xbap", "application/x-ms-xbap", _
    ".xps", "application/vnd.ms-xpsdocument")

Set MimeMapObj = GetObject("IIS://LocalHost/MimeMap")

For counter = 0 to UBound(MimeTypesToAddArray) Step 2
AddMimeType MimeTypesToAddArray(counter), MimeTypesToAddArray(counter+1)
Next

Set WshShell = CreateObject("WScript.Shell")

Set oExec = WshShell.Exec("net stop w3svc")
Do While oExec.Status = 0
WScript.Sleep 100
Loop

Set oExec = WshShell.Exec("net start w3svc")
Do While oExec.Status = 0
WScript.Sleep 100
Loop

Set oExec = Nothing

WScript.Echo "Windows Presentation Foundation MIME tipleri kaydedildi."

Sub AddMimeType (Ext, MType)

MimeMapArray = MimeMapObj.GetEx("MimeMap")

    i = UBound(MimeMapArray) + 1
    Redim Preserve MimeMapArray(i)
    Set MimeMapArray(i) = CreateObject("MimeMap")
    MimeMapArray(i).Extension = Ext
    MimeMapArray(i).MimeType = MType
    MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", MimeMapArray
    MimeMapObj.SetInfo

End Sub